Twitter の Public timeline をいくつか表示するだけ。
クリックで1つずつステータスを表示していく。
ソースコード(TwitterPlane.as)
package {
import flash.display.*;
import flash.events.*;
import flash.geom.*;
import flash.net.*;
import flash.system.*;
import flash.text.*;
import org.papervision3d.scenes.*;
import org.papervision3d.objects.*;
import org.papervision3d.cameras.*;
import org.papervision3d.materials.*;
[SWF(width="400", height="400", backgroundColor="#000000", frameRate="30")]
public class TwitterPlane extends Sprite {
private var container : Sprite;
private var scene : Scene3D;
private var camera : FreeCamera3D;
private var rootNode : DisplayObject3D;
private var obj:Array = new Array();
// 3Dオブジェクト踊らせ用パラメータ
private var valx : Number = 0;
private var valy : Number = 0;
private var twitter:Twitter;
public function TwitterPlane():void {
// リサイズに対応(swfをブラウザで直接ひらいているときとか)
stage.addEventListener(Event.RESIZE, onStageResize);
// 定期的にイベント発生
addEventListener(Event.ENTER_FRAME, myLoopEvent);
// マウスクリックでイベント発生
stage.addEventListener(MouseEvent.CLICK, myClick);
// 表示用の Sprite オブジェクトを生成
container = new Sprite();
container.x = 400 / 2; // at center : swf width = 400
container.y = 400 / 2; // at center : swf height = 400
addChild(container);
// シーンオブジェクトを作る
scene = new Scene3D(container);
// カメラオブジェクトを作る
camera = new FreeCamera3D();
camera.zoom = 1;
camera.focus = 1000;
//camera.z = -100;
// ルートノードを作る
rootNode = new DisplayObject3D();
scene.addChild(rootNode);
twitter = new Twitter();
}
private function myClick(event:MouseEvent):void {
var status:XML = twitter.getNextStatus();
if(status != null){
createPlane(status.text);
}
}
private function createPlane(text:String):void {
var canvas:PlaneCanvas = new PlaneCanvas(text);
canvas.canvas.x = Math.random() * 400 - 200;
canvas.canvas.y = Math.random() * 400 - 200;
canvas.canvas.z = Math.random() * 400 - 200;
canvas.canvas.rotationX = Math.random() * 360;
canvas.canvas.rotationY = Math.random() * 360;
canvas.canvas.rotationZ = Math.random() * 360;
obj.push(canvas);
rootNode.addChild(canvas.canvas);
if(obj.length > 30){
var head:PlaneCanvas = obj.shift() as PlaneCanvas;
rootNode.removeChild(head.canvas);
}
camera.x = canvas.canvas.x;
camera.y = canvas.canvas.y;
camera.z = canvas.canvas.z;
camera.rotationX = canvas.canvas.rotationX;
camera.rotationY = canvas.canvas.rotationY;
camera.rotationZ = canvas.canvas.rotationZ;
}
private function myLoopEvent(event:Event):void {
valx += container.mouseX / 50;
valy += container.mouseY / 50;
camera.rotationY = valx;
camera.rotationX = valy;
scene.renderCamera(camera);
}
private function onStageResize(event:Event):void {
container.x = stage.stageWidth / 2;
container.y = stage.stageHeight / 2;
}
}
}
ソースコード(PlaneCanvas.as)
package {
import flash.display.*;
import flash.events.*;
import flash.geom.*;
import flash.text.*;
import org.papervision3d.scenes.*;
import org.papervision3d.objects.*;
import org.papervision3d.cameras.*;
import org.papervision3d.materials.*;
public class PlaneCanvas extends Sprite {
// canvas
public var canvas:Plane;
public var canvasText:TextField;
public var canvasMaterial:MovieMaterial
public function PlaneCanvas(text:String):void {
this.canvasText = createTextField(text);
var mc:MovieClip = new MovieClip();
mc.addChild(canvasText);
this.canvasMaterial = createMovieMaterial(mc);
var w:int = text.length * 50;
var h:int = 50;
this.canvas = createTextPlane(canvasMaterial, w, h);
}
public function setText(text:String):void {
// update Text
//canvasText.border = !canvasText.border; // ワクを付けたり消したり
//canvasText.background = !canvasText.background; // 背景を付けたり消したり
canvasText.text = text;
canvasMaterial.updateBitmap(); // 更新を通知
}
private static function createTextPlane(material:MovieMaterial, width:int, height:int):Plane {
var width:int = width;
var height:int = height;
var segment:int = 4;
var plane:Plane = new Plane(
material, width, height, segment, segment);
return plane;
}
private static function createMovieMaterial(asset:MovieClip):MovieMaterial {
var transparent:Boolean = true;
var initObject:Object = {animated:true, doubleSided:true};
var material:MovieMaterial = new MovieMaterial(asset, transparent, initObject);
//material.oneSide = false;
//material.lineColor = 0x00FF00;
//material.lineAlpha = 1;
return material;
}
private static function createTextField(t:String):TextField {
// 表示メッセージのスタイル
var format:TextFormat = new TextFormat();
format.bold = false;
format.italic = false;
format.size = 10;
format.underline = false;
format.font = "_等幅";
// 表示メッセージ
var text:TextField = new TextField();
text.autoSize = TextFieldAutoSize.LEFT;
text.selectable = false;
text.setTextFormat(format);
text.background = false;
text.backgroundColor = 0xFF0000;
text.border = false;
text.borderColor = 0xFFFFFF;
text.textColor = 0xFFFFFF;
text.text = t;
return text;
}
}
}
ソースコード(Twitter.as)
package {
import flash.events.*;
import flash.net.*;
import flash.system.*;
public class Twitter {
// xml load
private var urlLoader:URLLoader;
private var statuses:Array;
public function Twitter():void {
statuses = new Array();
// xml loading
urlLoader = new URLLoader();
urlLoader.addEventListener(ProgressEvent.PROGRESS, urlLoaderProgress);
urlLoader.addEventListener(Event.COMPLETE, urlLoaderComplete);
urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, urlLoaderSecurityError);
urlLoader.addEventListener(IOErrorEvent.IO_ERROR, urlLoaderIoError);
urlLoader.load(new URLRequest("http://twitter.com/statuses/public_timeline.xml"));
// urlLoader.load(new URLRequest("http://twitter.com/statuses/friends_timeline.xml"));
}
private function urlLoaderProgress(event:ProgressEvent):void {
}
private function urlLoaderComplete(event:Event):void {
var xml:XML = new XML(urlLoader.data);
for(var i:int=0; i<xml.status.length(); i++){
statuses.push(xml.status[i]);
}
}
private function urlLoaderSecurityError(event:SecurityErrorEvent):void {
// Security Error
}
private function urlLoaderIoError(event:IOErrorEvent):void {
// IO Error
}
public function getNextStatus():XML{
if(statuses.length > 0){
return statuses.shift() as XML;
}else{
return null;
}
}
}
}
tags: zlashdot Flash Flash Flex Papervision3D
Posted by NI-Lab. (@nilab)